scores distribution of one of several quantities in a regular
spatial structure (binning) independent from the geometry:
(see also EVENTBIN for an event-by-event scoring, and USRBDX, USRCOLL,
USRTRACK for fluence estimators)
The full definition of the binning may require two successive cards
(the second card, identified by the character '&' in any column
from 71 to 78, must be given unless the corresponding defaults are
acceptable to the user)
First card:
WHAT(1) : code indicating the type of binning selected. Each type is
characterised by a number of properties:
- structure of the mesh (spatial: R-Z, R-Phi-Z, Cartesian, or
special - by region, or user-defined)
- quantity scored (energy, star, fission, neutron balance
specific activity or tracklength density)
- method used for scoring (old algorithm where the energy
lost in a step by a charged particle is deposited in the
middle of the step, or new algorithm where the energy lost
is apportioned among different bins according to the
relevant step fraction - see more in a note below)
- mesh symmetry (no symmetry, or specular symmetry around one
of the coordinate planes, or around the origin point)
0.0 : Mesh: Cartesian, no symmetry
Quantity scored:
- if WHAT(2) = 208, 211, 229 or 230: energy density (deposited
with the old algorithm at midstep)
- if WHAT(2) = 219, 220 or 221, fission density
- if WHAT(2) = 222, neutron balance density
- if WHAT(2) = 234 or 235, specific activity
- otherwise, density of stars produced by particles (or
families of particles) with particle code = WHAT(2)
1.0 : Mesh: R-Z or R-Phi-Z, no symmetry. Phi is the azimuthal angle
around the Z axis, measured from -pi to +pi relative to
the X axis.
Quantity scored: same as for WHAT(1) = 0.0
2.0 : Mesh: by region (1 bin corresponds to n regions, with n = 1 to 3)
Quantity scored: same as for WHAT(1) = 0.0
3.0 : Mesh: Cartesian, with symmetry +/- X (i.e. |x| is used for
scoring)
Quantity scored: same as for WHAT(1) = 0.0
4.0 : Mesh: Cartesian, with symmetry +/- Y (i.e. |y| is used for
scoring).
Quantity scored: same as for WHAT(1) = 0.0
5.0 : Mesh: Cartesian, with symmetry +/- Z (i.e. |z| is used for
scoring).
Quantity scored: same as for WHAT(1) = 0.0
6.0 : Mesh: Cartesian, with symmetry around the origin (i.e.
|x|, |y| and |z| are used for scoring)
Quantity scored: same as for WHAT(1) = 0.0
7.0 : Mesh: R-Z or R-Phi-Z, with symmetry +/- Z (i.e. |z| is used for
scoring)
Quantity scored: same as for WHAT(1) = 0.0
8.0 : Special user-defined 3D binning. Two variables are
discontinuous (e.g. region number), the third one is continuous,
but not necessarily a space coordinate. See 13} for instructions
on how to write, compile and link the user routines.
Variable # type default Override routine
1st integer region number MUSRBR
2nd integer lattice cell number LUSRBL
3rd continuous pseudorapidity FUSRBV
10.0 : Mesh: Cartesian, no symmetry
Quantity scored: if WHAT(2) = 208, 211, 229 or 230, energy
density (apportioned with the new algorithm along the step).
If WHAT(2) = 219, 220 or 221: fission density.
Otherwise, fluence (tracklength density) of particles
(or families of particles) with particle code = WHAT(2)
11.0 : Mesh: R-Z or R-Phi-Z, no symmetry
Quantity scored: same as for WHAT(1) = 10.0
12.0 : Mesh: by region (1 bin corresponds to n regions, with n = 1 to 3)
Quantity scored: same as for WHAT(1) = 10.0
13.0 : Mesh: Cartesian, with symmetry +/- X (|x| used for scoring)
Quantity scored: same as for WHAT(1) = 10.0
14.0 : Mesh: Cartesian, with symmetry +/- Y (|y| used for scoring)
Quantity scored: same as for WHAT(1) = 10.0
15.0 : Mesh: Cartesian, with symmetry +/- Z (|z| used for scoring)
Quantity scored: same as for WHAT(1) = 10.0
16.0 : Mesh: Cartesian, with symmetry around the origin (|x|,|y|,
|z| used for scoring)
Quantity scored: same as for WHAT(1) = 10.0
17.0 : Mesh: R-Z or R-Phi-Z, with symmetry +/- Z (|z| used for scoring)
Quantity scored: same as for WHAT(1) = 10.0
Default = 0.0 (Cartesian scoring without symmetry, star density or
energy density deposited at midstep with the old algorithm)
WHAT(2) : particle (or particle family) type to be scored
If WHAT(2) = 208, 211, 229 or 230:
If WHAT(1) < 10, the binning will score energy
deposition with the old algorithm.
If WHAT(1) >= 10, the new deposition algorithm will be used
(more accurate, see Note below).
Any other particle (or family of particles) requested will score:
a) if WHAT(1) < 10, density of stars produced by particles
(or family of particles) with particle code = WHAT(2).
Of course, this choice is meaningful only for particles which
can produce stars (hadrons, photons and muons).
b) if WHAT(1) >= 10, fluence of particles (or family of particles)
with particle code = WHAT(2).
Note that it is not possible to score energy fluence with
this option alone (it is possible, however, by writing a
special version of the user routine FLUSCW - see 13})
Default: 208.0 (total energy density)
WHAT(3) = logical output unit:
> 0.0 : formatted data are written on WHAT(3) unit
< 0.0 : unformatted data are written on |WHAT(3)| unit
Values of |WHAT(1)| < 21 should be avoided (with the
exception of +11).
Default: WHAT(3) = 11.0 (standard output unit)
WHAT(4) = For Cartesian binning: Xmax
For R-Z and R-Phi-Z binning: Rmax
For region binning: last region of the first region set
For special binnings, upper limit of the first
user-defined variable (last region if the default
version of the MUSRBR routine is not overridden)
No default
WHAT(5) = For Cartesian binning: Ymax
For R-Z binning: Y coordinate of the binning axis
(in R-Phi-Z binnings, the Y coordinate must be zero).
For region binning: last region of the second region set
For special binnings, upper limit of the second
user-defined variable (last lattice cell if the default
version of the LUSRBL routine is not overridden)
No default
WHAT(6) = For R-Z, R-Phi-Z and Cartesian binnings: Zmax
For region binnings, last region of the 3rd region set
For special binnings, upper limit of the 3rd
user-defined variable (eta_max if the default
version of the FUSRBV routine is not overridden)
No default
SDUM = any character string (not containing '&') identifying the
binning
Continuation card: (not needed if the defaults are acceptable)
WHAT(1) = For Cartesian binning: Xmin (if X symmetry is requested,
Xmin cannot be negative)
For R-Z and R-Phi-Z binning: Rmin
For region binnings, first region of the first region set
Default: equal to last region (= WHAT(4) in the first
USRBIN card)
For special binnings, lower limit of the first
user-defined variable (first region if the default
version of the MUSRBR routine is not overridden)
Default: 0.0
WHAT(2) = For Cartesian binning: Ymin (if Y symmetry is requested,
Ymin cannot be negative)
For R-Z binning: X coordinate of the binning axis
(in R-Phi-Z binnings, the X coordinate must be zero).
For region binnings, first region of the second region set
Default: equal to last region (= WHAT(5) in the first
USRBIN card)
For special binnings, lower limit of the second
user-defined variable (first lattice cell if the default
version of the LUSRBL routine is not overridden)
Default: 0.0
WHAT(3) = For Cartesian, R-Z and R-Phi-Z binnings: Zmin (if Z
symmetry is requested, Zmin cannot be negative)
For region binnings, first region of the third region set
Default: equal to last region (= WHAT(6) in the first
USRBIN card)
For special binnings, lower limit of the 3rd
user-defined variable (eta_min if the default
version of the FUSRBV routine is not overridden)
Default: 0.0
WHAT(4) = For Cartesian binning: number of X bins (default: 30.0)
For R-Z and R-Phi-Z binning: number of R bins (default: 50.0)
For region binnings, step increment for going from the
first to the last region of the first region set
(Default: 1)
For special binnings, step increment for going from
the first to the last "region" (or similar)
(Default: 1)
WHAT(5) = For Cartesian binning: number of Y bins (default: 30.0)
For R-Phi-Z: number of Phi bins (default is R-Z: 1 Phi bin)
For region binnings, step increment for going from the
first to the last region of the second region set
(Default: 1)
For special binnings, step increment for going from
the first to the last "lattice cell" (or similar)
(Default: 1)
WHAT(6) = For Cartesian, R-Z and R-Phi-Z binnings: number of Z bins
Default: 10.0 for Cartesian, 50.0 for R-Z and R-Phi-Z
For region binnings, step increment for going from the
first to the last region of the third region set
(Default: 1)
For special binnings, number of intervals for the
third variable ("eta", or similar)
(Default: 1)
SDUM = & in any position in column 71 to 78
Default (option USRBIN not given): no binning
Notes: A "binning" is a regular spatial mesh completely independent
from the regions defined by the problem's geometry. On user's
request, FLUKA can calculate the distribution of several different
quantities over one or more binning structures, separated or even
overlapping.
The following quantities can be "binned":
- energy density (dose), total or deposited by electrons, positrons
and gamma only
- star density (hadronic inelastic interactions)
- particle tracklength density (fluence)
- density of high-energy and low-energy fissions
- neutron balance density (algebraic sum of outgoing neutrons minus
incoming neutrons for all interactions)
- unbiased energy density (physically meaningless but useful for
setting biasing parameters and debugging)
The available binning shapes are Cartesian (3-D rectangular, with
planes perpendicular to the coordinate axes), R-Z (2-D cylindrical,
with the cylinder axis parallel to the z-axis), and R-Phi-Z (3-D
cylindrical).
It is possible to define also binnings with an arbitrary orientation
in space, by means of options ROT-DEFIni and ROTPRBIN.
A star is a hadronic inelastic interaction (spallation reaction)
at an energy higher than a threshold defined via the option
THRESHOLd (or by default higher than the transport threshold of
the interacting particle). Star scoring (traditionally used in most
high-energy shielding codes) can therefore be considered
as a form of crude collision estimator: multiplication of
star density by the asymptotic value of the inelastic
nuclear interaction length gives the fluence of hadrons
having energy higher than the current threshold. However,
this is meaningful only if the interaction length doesn't
vary appreciably with energy; therefore it is recommended
to set a scoring threshold = 50 MeV (using option THRESHOLd),
since interaction lengths are practically constant above this
energy. Besides, star densities calculated with a 50 MeV
threshold are the basis of some established radiation
protection techniques such as the omega-factors for estimating
material activation [Tho88, p.106], and the prediction of single
isotope yields from the ratio of partial to inelastic cross section).
Selecting star scoring is meaningful for hadrons, photons and
muons (if their energy is sufficiently high). Any other particle
will not produce any star. And in FLUKA, stars do not include
spallations due to annihilating particles.
The results will be expressed in stars per cm3 per unit primary
weight.
Energy deposition will be expressed in GeV per cm3 per unit
primary weight. To obtain doses (in Gy per unit primary weight),
the results must be multiplied by (1.602176462E-7 / rho), where
rho is the material density in g/cm3. The multiplication may be
done off-line by an analysis program, or on-line at the time of
scoring by linking a user-written routine COMSCW (see 13}). The
latter choice allows to calculate the correct average dose even
in bins straddling the boundary between two regions of different
density.
The results from USRBIN are normalised per unit volume and
per unit primary weight, except for region binnings which are
normalised per unit primary weight only. In case symmetries
are requested proper rescaled volumes are taken into account
for normalisation (that is, an extra factor 2 is applied to
the volume if symmetry around one axis is required, 8 if
symmetry around the origin is required)
When scoring energy deposition (generalised particles 208
and 211), it is recommended to set in the first USRBIN card
WHAT(1) = 10.0, 11.0, ...., 17 (rather than 0.0, 1.0, ..., 7.0).
The difference between the two settings is the following.
With WHAT(1) = 0.0, 1.0, ..., 7.0, the energy lost in a charged
particle step is deposited in the bin corresponding to the midpoint
of the step: this is the old FLUKA algorithm, which is rather
inefficient when the step length is larger than the bin size.
The new algorithm, selected by setting WHAT(1) = 10.0, 11.0,
...., 17, deposits in every bin traversed by the step a
fraction of energy proportional to the respective chord
(track-length apportioning). Statistical convergence is
much faster.
When scoring region binning and more than one set of regions is
defined, each of the sets (2 or 3) must have the same number of
regions. The first bin will contain the sum of what is contained
in the first regions of each set, the second bin the sum of
the scores of the second regions, etc.
The maximum number of binnings that the user can define is
100. This value can be changed by modifying the parameter
MXUSBN in member USRBIN of the flukapro library or directory
and then re-compiling and linking FLUKA.
The logical output unit for the estimator results (WHAT(3) of
the first USRBIN card) can be any one of the following:
- the standard output unit 11: estimator results will be
written on the same file as the standard FLUKA output
- a pre-connected unit (via a symbolic link on most UNIX systems,
ASSIGN under VMS, or equivalent commands on other systems)
- a file opened with the FLUKA command OPEN
- a file opened with a Fortran OPEN statement in a user-written
initialisation routine such as USRINI or SOURCE (see 13}).
- a dynamically opened file, with a default name assigned by the
Fortran compiler (typically fort.xx or ftn.xx, with xx equal
to the chosen logical output unit number).
The results of several USRBIN detectors in a same FLUKA run can be
written on the same file, but of course only if they are all in the
same mode (all formatted, or all unformatted).
It is also possible in principle to write on the same file the
results of different kinds of estimators (USRBDX, USRTRACK, etc.)
but this is not recommended, especially in the case of an
unformatted file, because it would make very difficult any reading
and analysis.
In R-Phi-Z binnings, the azimuthal Phi coordinates extend from -pi to
+pi (-180 to +180 degrees). Phi = 0 corresponds to the x-axis.
Binning data can be obtained also separately for each
"event" ("event" = history of a primary particle and all its
descendants). See option EVENTBIN for details.
An example on how to read USRBIN unformatted output
is given below. An explanation of the meaning of the different
variables is given in the comments at the beginning of the program.
The programs lists for each bin its boundaries and the corresponding
scored quantity.
Two more complex programs, USBSUW and USBREA, are
available with the normal FLUKA code distribution in directory
$FLUPRO/flutil. USBSUW allows to compute standard
deviations over several runs, and returns the standard
deviations and the averages in an unformatted file. USBREA
reads an unformatted file and returns the equivalent formatted file,
including the standard deviations if the input file was produced
by USBSUW.
PROGRAM RDBIN
*----------------------------------------------------------------------*
* Up to MXUSBN user defined binnings are allowed *
* itusbn = type of binning (must be decoded if .ge. 10) *
* idusbn = distribution to be scored: usual values allowed *
* titusb = binning name *
* nxbin = number of x (r for RZ) intervals *
* nybin = number of y (1 for RZ) intervals *
* nzbin = number of z intervals *
* xlow/high = minimum and maximum x (r for R-Phi-Z) *
* ylow/high = minimum and maximum y (phi for R-Phi-Z) *
* zlow/high = minimum and maximum z *
* dxusbn = x (r) bin width *
* dyusbn = y (Phi) bin width *
* dzusbn = z bin width *
* tcusbn = time cut-off (seconds) for this binning *
* bkusbn = 1st Birk's law parameter for this binning *
* (meaningful only for energy scoring) *
* b2usbn = 2nd Birk's law parameter for this binning *
* (meaningful only for energy scoring) *
* xaxusb = x-axis offset for R-Z binning (not possible for R-Phi-Z)*
* yaxusb = y-axis offset for R-Z binning (not possible for R-Phi-Z)*
**----------------------------------------------------------------------*
PARAMETER ( MXUSBN = 100 ) ! max. number of binnings
PARAMETER ( MXSCOR = 500000 ) ! storage for results
LOGICAL LUSBIN, LUSEVT, LUSTKB
CHARACTER RUNTIT*80, RUNTIM*32, TITUSB*10, FILNAM*80, CHSTAT*10
DIMENSION MB(MXUSBN),XLOW(MXUSBN), XHIGH(MXUSBN), YLOW(MXUSBN),
& YHIGH (MXUSBN), ZLOW (MXUSBN), ZHIGH (MXUSBN), DXUSBN(MXUSBN),
& DYUSBN(MXUSBN), DZUSBN(MXUSBN), TCUSBN(MXUSBN), BKUSBN(MXUSBN),
& B2USBN(MXUSBN), NXBIN (MXUSBN), NYBIN (MXUSBN), NZBIN (MXUSBN),
& ITUSBN(MXUSBN), IDUSBN(MXUSBN), KBUSBN(MXUSBN), IPUSBN(MXUSBN),
& LEVTBN(MXUSBN), LNTZER(MXUSBN), LTRKBN(MXUSBN), TITUSB(MXUSBN),
& XAXUSB(MXUSBN), YAXUSB (MXUSBN), SCORED(MXSCOR)
WRITE(*,*) ' Type the name of the input file:'
READ (*,'(A)') FILNAM
LQ = INDEX(FILNAM,' ') - 1
OPEN (UNIT=1, FILE=FILNAM, STATUS='OLD', FORM='UNFORMATTED')
OPEN (UNIT=2, FILE=FILNAM(1:LQ)//'.txt', STATUS='NEW')
*----------- read and write 1st record ---------------------------------
READ (1) RUNTIT, RUNTIM, WEIPRI, NCASE
WRITE(2,100) RUNTIT, RUNTIM, NCASE, WEIPRI
*----------- loop on binning detector data in the present file ---------
DO 1 IB = 1, MXUSBN
NB = IB
* ---------------- read and write 2nd record --------------------
READ (1,END=1000) MB(NB), TITUSB(NB), ITUSBN(NB), IDUSBN(NB),
& XLOW(NB), XHIGH(NB), NXBIN(NB), DXUSBN(NB), YLOW(NB),
& YHIGH(NB), NYBIN(NB), DYUSBN(NB), ZLOW(NB), ZHIGH(NB),
& NZBIN(NB), DZUSBN(NB), LNTZER(NB), BKUSBN(NB), B2USBN(NB),
& TCUSBN(NB)
ITUHLP = MOD (ITUSBN(NB),10)
IF ( ITUHLP .EQ. 2) THEN
* Region binning
NBIN = MAX(NXBIN(NB),NYBIN(NB),NZBIN(NB))
IR1A = NINT(XLOW(NB))
IR1B = NINT(XHIGH(NB))
IDR1 = NINT(DXUSBN(NB))
IR2A = NINT(YLOW(NB))
IR2B = NINT(YHIGH(NB))
IDR2 = NINT(DYUSBN(NB))
IR3A = NINT(ZLOW(NB))
IR3B = NINT(ZHIGH(NB))
IDR3 = NINT(DZUSBN(NB))
READ(1) (SCORED(J), J = 1, NBIN)
WRITE(2,101) MB(NB), TITUSB(NB), IDUSBN(NB), NBIN,
& IR1A, IR1B, IDR1, IR2A, IR2B, IDR2, IR3A, IR3B, IDR3
DO 2 I = 1, NBIN
WRITE(2,1010) IR1A + (I-1)*IDR1, IR2A + (I-1)*IDR2,
& IR3A + (I-1)*IDR3, SCORED(I)
2 CONTINUE
ELSE IF ( ITUHLP .EQ. 8 ) THEN
* Region/Lattice/User binning
IR1A = NINT(XLOW(NB))
IR1B = NINT(XHIGH(NB))
IDR1 = NINT(DXUSBN(NB))
IR2A = NINT(YLOW(NB))
IR2B = NINT(YHIGH(NB))
IDR2 = NINT(DYUSBN(NB))
READ(1) (SCORED(J), J = 1, NXBIN(NB)*NYBIN(NB)*NZBIN(NB))
WRITE(2,102) MB(NB), TITUSB(NB), IDUSBN(NB), NXBIN(NB),
& IR1A, IR1B, IDR1, IR2A, IR2B, IDR2, ZLOW(NB), ZHIGH(NB),
& NZBIN(NB), DZUSBN(NB)
J = 0
IR1 = IR1A
IR2 = IR2A
UVAR = ZLOW(NB)
DO 3 IZ = 1, NZBIN(NB)
DO 4 IY = 1, NYBIN(NB)
DO 5 IX = 1, NXBIN(NB)
J = J + 1
WRITE(2,1020) IR1, IR1 + IDR1, IR2, IR2 + IDR2,
& UVAR, UVAR + DZUSBN(NB), SCORED(J)
IR1 = IR1 + IDR1
5 CONTINUE
IR1 = IR1A
IR2 = IR2 + IDR2
WRITE(2,*)
4 CONTINUE
IR2 = IR2A
UVAR = UVAR + DZUSBN(NB)
WRITE(2,*)
3 CONTINUE
ELSE IF ((ITUHLP.EQ.1.OR.ITUHLP.EQ.7).AND.NYBIN(NB).LT.2) THEN
* R-Z binning
* XAXUSB(NB) = YLOW (NB)
* YAXUSB(NB) = YHIGH(NB)
NBIN = NXBIN(NB) * NZBIN(NB)
READ(1) (SCORED(J), J = 1, NBIN)
WRITE(2,103) MB(NB), TITUSB(NB), IDUSBN(NB), XLOW(NB),
& XHIGH(NB), NXBIN(NB), DXUSBN(NB), ZLOW(NB), ZHIGH(NB),
& NZBIN(NB), DZUSBN(NB) !, XAXUSB(NB), YAXUSB(NB)
J = 0
RR = XLOW(NB)
ZZ = ZLOW(NB)
DO 6 IZ = 1, NZBIN(NB)
DO 7 IX = 1, NXBIN(NB)
J = J + 1
WRITE(2,1030) RR, RR+DXUSBN(NB), ZZ, ZZ+DZUSBN(NB),
& SCORED(J)
RR = RR + DXUSBN(NB)
7 CONTINUE
RR = XLOW(NB)
ZZ = ZZ + DZUSBN(NB)
WRITE(2,*)
6 CONTINUE
ELSE IF ( ITUHLP.EQ.1.OR.ITUHLP.EQ.7 ) THEN
* R-Phi-Z binning
NBIN = NXBIN(NB) * NYBIN(NB) * NZBIN(NB)
READ(1) (SCORED(J), J = 1, NBIN)
WRITE(2,104) MB(NB), TITUSB(NB), IDUSBN(NB), XLOW(NB),
& XHIGH(NB), NXBIN(NB), DXUSBN(NB), YLOW(NB), YHIGH(NB),
& NYBIN(NB), DYUSBN(NB), ZLOW(NB), ZHIGH(NB), NZBIN(NB),
& DZUSBN(NB)
J = 0
RR = XLOW(NB)
PH = YLOW(NB)
ZZ = ZLOW(NB)
DO 8 IZ = 1, NZBIN(NB)
DO 9 IY = 1, NYBIN(NB)
DO 10 IX = 1, NXBIN(NB)
J = J + 1
WRITE(2,1040) RR, RR + DXUSBN(NB), PH,
& PH + DYUSBN(NB), ZZ, ZZ + DZUSBN(NB), SCORED(J)
RR = RR + DXUSBN(NB)
10 CONTINUE
RR = XLOW(NB)
PH = PH + DYUSBN(NB)
WRITE(2,*)
9 CONTINUE
PH = YLOW(NB)
ZZ = ZZ + DZUSBN(NB)
WRITE(2,*)
8 CONTINUE
ELSE IF ( ITUHLP .EQ. 0 ) THEN
* Cartesian binning
NBIN = NXBIN(NB) * NYBIN(NB) * NZBIN(NB)
READ(1) (SCORED(J), J = 1, NBIN)
WRITE(2,105) MB(NB), TITUSB(NB), IDUSBN(NB), XLOW(NB),
& XHIGH(NB), NXBIN(NB), DXUSBN(NB), YLOW(NB), YHIGH(NB),
& NYBIN(NB), DYUSBN(NB), ZLOW(NB), ZHIGH(NB), NZBIN(NB),
& DZUSBN(NB)
J = 0
XX = XLOW(NB)
YY = YLOW(NB)
ZZ = ZLOW(NB)
DO 11 IZ = 1, NZBIN(NB)
DO 12 IY = 1, NYBIN(NB)
DO 13 IX = 1, NXBIN(NB)
J = J + 1
WRITE(2,1040) XX, XX + DXUSBN(NB), YY,
& YY + DYUSBN(NB), ZZ, ZZ + DZUSBN(NB), SCORED(J)
XX = XX + DXUSBN(NB)
13 CONTINUE
XX = XLOW(NB)
YY = YY + DYUSBN(NB)
WRITE(2,*)
12 CONTINUE
YY = YLOW(NB)
ZZ = ZZ + DZUSBN(NB)
WRITE(2,*)
11 CONTINUE
END IF
1 CONTINUE ! end loop on detectors
* ------------------------------------------------------------------
1000 CONTINUE
100 FORMAT(/,1X,'*****',2X,A80,2X,'*****',/,/,10X,A32,/,/,
& 10X,'Total number of particles followed ',I9,', for a ',
& 'total weight of ',1P,E15.8,/)
101 FORMAT (/, 3X, 'Region binning n. ', I3, ' "', A10,
& '" , generalised particle n. ', I4, /, 6X, I5,
& ' bins corresponding to the region sets:' /, 6X, 'from region ',
& I5, ' to region ', I5, ' in step of ', I5, ' regions, or', /,
& 6X, 'from region ', I5, ' to region ', I5, ' in step of ', I5,
& ' regions, or', /, 6X, 'from region ', I5, ' to region ', I5,
& ' in step of ', I5, ' regions',//, 7X, 'Set 1', 5X, 'Set 2',
& 5X, 'Set 3', 6X, 'Score',/)
102 FORMAT (/, 3X, 'Reg/Lat/U binning n. ', I3, ' "', A10,
& '" , generalised particle n. ',I4, /, 6X, I5,
& ' bins corresponding to the region-related set:' /, 6X,
& 'from region ', I5, ' to region ', I5, ' in step of ', I5,
& ' regions, and', /, 6X, I5,
& ' bins corresponding to the lattice-related set:' /, 6X,
& 'from lattice', I5, ' to lattice', I5, ' in step of ', I5,
& ' lattices, and', /, 6X, 'U coordinate: from ', 1P, E11.4,
& ' to ', E11.4, ' ux, ', 0P, I5, ' bins (', 1P, E11.4,
& ' ux wide)', /)
103 FORMAT('1', /, 3X, 'R - Z binning n. ', I3, ' "', A10,
& '" , generalised particle n. ', I4,/, 6X, 'R coordinate: from ',
& 1P, E11.4, ' to ', E11.4, ' cm, ', 0P, I5, ' bins (', 1P, E11.4,
& ' cm wide)', /, 6X, 'Z coordinate: from ', 1P, E11.4, ' to ',
& E11.4, ' cm, ', 0P, I5, ' bins (', 1P, E11.4, ' cm wide)', //,
& ' between R1',2X, 'and', 5X, 'R2', 13X, 'between Z1', 2X, 'and',
& 5X, 'Z2', 15X, 'Score', /)
* & 6X, 'axis coordinates: X =', 1P, E11.4, ', Y = ', E11.4, ' cm'/
104 FORMAT('1', /, 3X, 'R-Phi-Z binning n. ', I3, ' "', A10,
& '" , generalised particle n. ', I4,/, 6X,
& 'R coordinate: from ',1P, E11.4, ' to ', E11.4, ' cm, ', 0P,
& I5, ' bins (', 1P, E11.4, ' cm wide)', /, 6X,
& 'Phi coordinate: from ', 1P, E11.4, ' to ', E11.4, ' rad, ', 0P,
& I5, ' bins (', 1P, E11.4, ' rad wide)', /, 6X,
& 'Z coordinate: from ', 1P, E11.4, ' to ', E11.4, ' cm,', 0P,
& I5, ' bins (', 1P, E11.4, ' cm wide)', //, ' between R1',1X,
& 'and', 4X, 'R2', 11X, 'between Phi1', 1X, 'and', 2X, 'Phi2',
& 10X, 'between Z1', 1X, 'and', 4X, 'Z2', 13X, 'Score', /)
105 FORMAT('1', /, 3X, 'Cartesian binning n. ', I3, ' "', A10,
& '" , generalised particle n. ', I4,/, 6X, 'X coordinate: from ',
& 1P, E11.4, ' to ', E11.4, ' cm, ', 0P, I5, ' bins (', 1P, E11.4,
& ' cm wide)', /, 6X, 'Y coordinate: from ', 1P, E11.4, ' to ',
& E11.4, ' cm, ', 0P, I5, ' bins (', 1P, E11.4, ' cm wide)',/, 6X,
& 'Z coordinate: from ', 1P, E11.4, ' to ', E11.4, ' cm, ', 0P,I5,
& ' bins (', 1P, E11.4, ' cm wide)' //, ' between X1',1X,
& 'and', 4X, 'X2', 12X, 'between Y1', 1X, 'and', 3X, 'Y2',
& 12X, 'between Z1', 1X, 'and', 4X, 'Z2', 13X, 'Score', /)
1010 FORMAT(3I10, 5X, 1P, E11.4)
1020 FORMAT(I11, 4X, I11, 5X, I11, 4X, I11, 5X, 1P, E11.4, 4X, E11.4,
& 6X, E11.4)
1030 FORMAT(1P, E11.4, 5X, E11.4, 6X, E11.4, 5X, E11.4, 8X, E11.4)
1040 FORMAT(1P, E11.4, 4X, E11.4, 5X, E11.4, 4X, E11.4, 5X, E11.4, 4X,
& E11.4, 6X, E11.4)
END
Example:
*...+....1....+....2....+....3....+....4....+....5....+....6....+....7...+...8
USRBIN 10.0 3.0 -25.0 7.0 7.0 12.1 verythin
USRBIN -7.0 -7.0 12.0 35.0 35.0 1.0 &
* Cartesian binning of electron tracklength density, to be written
* unformatted on unit 25. Mesh is 35 bins between x = -7 and x = 7, 35 bins
* between y = -7 and y = 7, and 1 bin between z = 12 and z = 12.1
